build.gradle

buildscript {
    repositories {
        maven {
            name = "forge"
            url = "https://maven.minecraftforge.net"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath "com.anatawa12.forge:ForgeGradle:2.3-1.0.8"
    }
}

apply plugin: 'net.minecraftforge.gradle.forge'

repositories {
    mavenCentral()
    maven { url "https://dvs1.progwml6.com/files/maven" }
    maven { url "https://modmaven.dev" }
    maven { url "https://maven.thiakil.com" }
    maven { url "https://maven.blamejared.com" }
    maven { url "https://cursemaven.com" }
}

group = 'xreliquary'
version = "${minecraft_version}-${mod_version}"
archivesBaseName = 'Reliquary'

dependencies {
    deobfCompile "mezz.jei:jei_${minecraft_version}:${jei_version}"
    deobfCompile "curse.maven:hwyla-253449:${hwyla_version}"
    deobfCompile "curse.maven:jer-240630:${jer_version}"
    deobfCompile "com.azanor.baubles:Baubles:${baubles_version}"
    deobfCompile "curse.maven:botania-225643:${botania_version}"
    deobfCompile "slimeknights.mantle:Mantle:${mantle_version}"
    deobfCompile "slimeknights:TConstruct:${tconstruct_version}"

    testCompile 'org.testng:testng:6.9.10'
    testCompile "org.mockito:mockito-core:1.+"
    testCompile "org.powermock:powermock-mockito-release-full:1.6.2"
}

test {
    useTestNG()
}

minecraft {
    version = minecraft_version + "-" + forge_version
    mappings = mcp_mappings
    runDir = "run"
    replaceIn "reference/Reference.java"
    replace "@MOD_VERSION@", "${project.version}"
}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "project_version", project.version
    inputs.property "minecraft_version", minecraft_version

    // Replace stuff in mcmod.info and in .lang files, nothing else.
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        // Replace version and mcversion.
        expand 'project_version': project.version, 'minecraft_version': minecraft_version
    }

    // Copy everything else that wasn't replaced.
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}