build.gradle

subprojects {
	apply plugin: "java"

	group project.maven_group
	version "${rootProject.properties.mod_version}+${rootProject.properties.minecraft_version}"

	base {
		archivesName = "${rootProject.archives_base_name}-${project.properties.loader_name}"
	}

	dependencies {
		annotationProcessor 'systems.manifold:manifold-preprocessor:+'
		implementation 'com.google.code.findbugs:jsr305:+'
	}

	repositories {
		mavenCentral()
		flatDir { dirs "../libs" }
		maven { url "https://jitpack.io" }
	}

	def mc_ver = rootProject.properties.minecraft_version
	def mc_major = mc_ver.split("\\.")[0]
	def mc_main = mc_ver.split("\\.")[1]
	def mc_minor = mc_ver.split("\\.").size() > 2 ? (mc_ver.split("\\.")[2] as String).padLeft(2, '0') : 0
	def merged_mc_version = "$mc_major$mc_main$mc_minor"

	ext { // Expose to subproject
		java_version =
				(merged_mc_version as int) <= 11605 ? 8 :
				(merged_mc_version as int) <= 11701 ? 16 :
				(merged_mc_version as int) <= 12004 ? 17 :
				21

		lg_unicode = (mc_main as int) <= 19 ? rootProject.properties.legacy_unicode_font : ""
		door_blockstate = (mc_main as int) <= 18 ? rootProject.properties.mc_door_118 : rootProject.properties.mc_door_119
	}

	/* Manifold support */
	tasks.withType(JavaCompile).forEach {
		it.options.compilerArgs += [
				"-Xplugin:Manifold",
				"-AMC_VERSION=$merged_mc_version",
				"-ALOADER=$project.properties.loader_name"
		]
	}

	// Some system don't compile with UTF-8 by default
	compileJava {
		options.encoding = 'UTF-8'
	}

	tasks.register('moveBuildFile', Copy) {
		from "${project.projectDir}/build/libs/${base.archivesName.get()}-${version}.jar"
		into "${rootProject.projectDir}/build"
	}
}