build.gradle

//file:noinspection GroovyAssignabilityCheck
plugins {
	// Dependencies
	id 'fabric-loom' version '0.12-SNAPSHOT'
	// Mod Hosting Publish
	id 'com.matthewprenger.cursegradle' version '1.4.0'
	id 'com.modrinth.minotaur' version '1.1.0'
	// Maven Publish
	id 'maven-publish'
	id 'signing'
	id 'io.codearte.nexus-staging' version '0.30.0'
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = "${archives_base_name}-Fabric"
version = "${project.mod_version}+${project.minecraft_version}"
group = project.maven_group
if (project.hasProperty('SNAPSHOT')) {
	version = "${version}-SNAPSHOT"
}
def mainArtifactFile = new File(new File(buildDir, 'libs'), "$archivesBaseName-${version}.jar")
def changelogFile = file('changelog.txt')

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings loom.officialMojangMappings()
	modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader_version}"

	compileOnly 'com.google.code.findbugs:jsr305:3.0.2'
}

processResources {
	inputs.property 'version', project.version

	def buildProps = project.properties.clone()

	filesMatching('*.mixins.json') {
		expand "refmap_target": "${archivesBaseName}-"
	}

	filesMatching(['**/*.json', 'pack.mcmeta']) {
		expand buildProps
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = 'UTF-8'
	it.options.release.set(17);
}

java {
	withJavadocJar()
	withSourcesJar()
}

javadoc.options.addStringOption('Xdoclint:none', '-quiet')

jar {
	from('LICENSE') {
		rename { "${it}_${project.archivesBaseName}"}
	}
}

if (hasProperty('curseForgeApiKey')) {
	curseforge {
		apiKey = curseForgeApiKey
		project {
			id = '412568'
			changelog = changelogFile
			releaseType = project.release_type
			addGameVersion project.minecraft_version
			addGameVersion 'Java 17'
			addGameVersion 'Fabric'
			addGameVersion 'Quilt'
			mainArtifact(mainArtifactFile) {
				displayName = "$archivesBaseName-$version"
			}
		}
		options {
			javaIntegration = false
			forgeGradleIntegration = false
		}
	}
}

import com.modrinth.minotaur.TaskModrinthUpload
if (hasProperty('modrinthApiKey')) {
	task publishModrinth(type: TaskModrinthUpload) {
		token = modrinthApiKey
		projectId = '9q1j6H6P'
		versionNumber = version
		versionName = project.mod_version
		uploadFile = mainArtifactFile
		changelog = changelogFile.getText()
		releaseType = project.release_type
		addGameVersion(project.minecraft_version as String)
		addLoader('fabric')
		addLoader('quilt')
	}
}

if (hasProperty('nexusUsername') || System.getenv("NEXUS_USERNAME") != null) {
	publishing {
		publications {
			mavenJava(MavenPublication) {
				from components.java
				groupId project.maven_group
				artifactId project.archivesBaseName
				version project.version
				pom {
					name = project.readable_name
					packaging = 'jar'
					description = project.maven_description
					url = project.modrinth_url
					scm {
						connection = "scm:svn:${project.github_url}.git"
						developerConnection = "scm:svn:${project.github_url}.git"
						url = project.github_url
					}

					licenses {
						license {
							name = project.license_name
							url = project.license_url
						}
					}

					developers {
						developer {
							id = 'the_fireplace'
							name = 'The_Fireplace'
							email = 'git@the-fireplace.dev'
						}
					}
				}
			}
		}
		repositories {
			maven {
				def releasesRepoUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
				def snapshotsRepoUrl = 'https://oss.sonatype.org/content/repositories/snapshots/'
				url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
				credentials {
					username = findProperty('nexusUsername') ?: System.getenv("NEXUS_USERNAME")
					password = findProperty('nexusPassword') ?: System.getenv("NEXUS_PASSWORD")
				}
			}
		}
	}

	signing {
		sign publishing.publications.mavenJava
	}
}