build.gradle

/*
 * Copyright 2022 Thoughtworks, Inc.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'java'
apply from: "https://raw.githubusercontent.com/gocd/gocd-plugin-gradle-task-helpers/master/helper.gradle?_=${(int) (new Date().toInstant().epochSecond / 60)}"

gocdPlugin {
  id = 'cd.go.authentication.ldap'
  pluginVersion = '2.3.0'
  goCdVersion = '22.1.0'
  name = 'LDAP Authentication Plugin for GoCD'
  description = 'LDAP Authentication Plugin for GoCD'
  vendorName = 'Thoughtworks, Inc.'
  vendorUrl = 'https://github.com/gocd/gocd-ldap-authentication-plugin'

  githubRepo {
    owner = System.getenv('GITHUB_USER') ?: 'bob'
    repo = 'gocd-ldap-authentication-plugin'
    token = System.getenv('GITHUB_TOKEN') ?: 'bad-token'
  }

  pluginProject = project

  prerelease = !"No".equalsIgnoreCase(System.getenv('PRERELEASE'))
  assetsToRelease = [project.tasks.jar]

  licenseReport {
    excludeGroups = ["cd.go.plugin.base"]
  }
}

group = 'cd.go'
version = gocdPlugin.fullVersion(project)

repositories {
  mavenCentral()
  mavenLocal()
}

java {
  sourceCompatibility = JavaVersion.VERSION_17
  targetCompatibility = JavaVersion.VERSION_17
}

sourceSets {
  integrationTest {
    java.srcDirs = ['src/integration']
    resources.srcDirs += ['src/testdata']
    compileClasspath += sourceSets.main.output
    runtimeClasspath += sourceSets.main.output
  }
}

configurations {
  integrationTestImplementation.extendsFrom testImplementation
  integrationTestRuntimeOnly.extendsFrom testRuntimeOnly
}

ext {
  deps = [
    gocdPluginApi: 'cd.go.plugin:go-plugin-api:24.4.0',
    apacheDs: 'org.apache.directory.server:apacheds-core:2.0.0.AM27',
  ]

  versions = project.ext.deps.collectEntries { lib, libGav -> [lib, libGav.split(':').last()] }
}

dependencies {
  compileOnly project.deps.gocdPluginApi
  implementation group: 'com.google.code.gson', name: 'gson', version: '2.11.0'
  implementation group: 'cd.go.plugin.base', name: 'gocd-plugin-base', version: '0.0.8'
  implementation group: 'org.apache.directory.api', name: 'api-ldap-client-api', version: '1.0.3'
  constraints {
    implementation('org.apache.mina:mina-core:2.0.27') {
      because "api-ldap-client-api use an older MINA 2.0 version"
    }
  }

  testImplementation project.deps.gocdPluginApi
  testImplementation group: 'org.mockito', name: 'mockito-core', version: '5.15.2'
  testImplementation group: 'org.skyscreamer', name: 'jsonassert', version: '1.5.3'
  testImplementation group: 'org.assertj', name: 'assertj-core', version: '3.27.2'
  testImplementation platform('org.junit:junit-bom:5.11.4')
  testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api'
  testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-params'
  testImplementation 'uk.org.webcompere:system-stubs-jupiter:2.1.7'
  testRuntimeOnly group: 'org.junit.jupiter', name: 'junit-jupiter-engine'
  testRuntimeOnly group: 'org.junit.platform', name: 'junit-platform-launcher'

  integrationTestImplementation group: 'com.github.stefanbirkner', name: 'system-rules', version: '1.19.0'
  integrationTestImplementation group: 'org.slf4j', name: 'slf4j-simple', version: '2.0.5'
  integrationTestImplementation project.deps.apacheDs
  integrationTestImplementation group: 'org.apache.directory.server', name: 'apacheds-core-annotations', version: project.versions.apacheDs
  integrationTestImplementation group: 'org.apache.directory.server', name: 'apacheds-core-integ', version: '2.0.0-M24'
  integrationTestImplementation group: 'org.apache.directory.server', name: 'apacheds-core-jndi', version: project.versions.apacheDs
  integrationTestImplementation group: 'org.apache.directory.server', name: 'apacheds-core-constants', version: project.versions.apacheDs
  integrationTestRuntimeOnly group: 'org.junit.vintage', name: 'junit-vintage-engine'
}

test {
  useJUnitPlatform()
}

task integrationTest(type: Test, description: 'Runs the ldap integration tests.', group: 'Verification') {
  testClassesDirs = sourceSets.integrationTest.output.classesDirs
  classpath = sourceSets.integrationTest.runtimeClasspath

  mustRunAfter tasks.test
  useJUnitPlatform()
}

check.dependsOn integrationTest

jar {
  from(configurations.runtimeClasspath) {
    into "lib/"
  }
}