Defining fallback functions for testing in Ink Editor

[afejesrichard]

Hello,

I'm creating Ink files for my dialogue mechanic in Unity. I'm also implementing external functions for the game engine to deal with these, however in the Ink Editor I cannot get past this error:
ERROR: Missing function binding for external: 'SetTestBool1' , and no fallback ink function found.

It's an external function that works with C# and the game engine.
I've tried to look up the problem and solutions, and I could find a thread with partial solution: #152
However, I still got two errors after implementing the suggested solution.

The 2 errors are:
Function call to 'SetTestBool1' requires 0 arguments, but got 1

My code looks like this:

VAR playerName = "Test"
VAR testVar = 5
EXTERNAL GetTestBool1()
EXTERNAL SetTestBool1(true)

->test_scene
=== test_scene ===
Welcome, stranger!

* [You greet the fellow.]
Well it's great to see you, {playerName}!
    ->test_scene

* Hi! Who are you?
    ->test_scene_2
* [Let's test!]
    ->testrail

* [You leave.]
 Goodbye then!
    -> END
    
=== testrail ===
Hi. Let's test this out.
Currently the Bool is <> 
{ GetTestBool1() == true:
TRUE!
- else:
FALSE!
}

+ [Set the bool true]
Alright, let's set it true!
{SetTestBool1(true)}
    -> testrail
    

+ [Set the bool false]
Alright, make it false!
{SetTestBool1(false)}
    -> testrail

* [You exit the dialogue]
    -> END

    
=== test_scene_2 ===
My name is Avakan, the Cloudleaper!
And you are The Stranger.
~ playerName = "The Stranger"

* [You are overwhelmed.]
I need to go think now.
I am {playerName}.
    -> END

* [You say goodbye.]
    -> END
    
    == function GetTestBool1() ==
~ return
    == function SetTestBool1() ==
~ return

I'd appreciate any kind of advice! 🙏

[joningold]

These two don't match parameters; also the external function def is supposed to name parameters (the parameters aren't used by ink, so it's just a way of telling the compiler how many to expect, but still - you can't use "true").

So

EXTERNAL SetTestBool1(true)
    == function SetTestBool1() ==
~ return

should be

EXTERNAL SetTestBool1(booleanVar)
    == function SetTestBool1(booleanVar) ==
~ return

You're also going to need your ink fallback for "getTestBool" to return something, or you'll hit an error when inky tries to use it.

    == function GetTestBool1() ==
~ return true

Note I quite often use "return RANDOM(0,1)" for this kind of fallback, so I can test different paths, but your use-case might not want that.

[afejesrichard]

Thanks! This is definitely works like a charm!
I think I still lack the proper knowledge of coding...