nsdp-config

#!/usr/bin/perl -w

#######################################################################
#
# NSDP discovery script v.1.0b
# Copyright 2012 Konstantin S. Vishnivetsky
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.
#
# For contacts:
# WEB: http://www.vishnivetsky.ru
# E-mail: kos@vishnivetsky.ru
# SkyPE: kvishnivetsky
# ICQ: 328-468-511
# Phone: +7 913 774-7588
#
#######################################################################

use strict;
use utf8;
use IO::Select;
use IO::Socket;
use Data::Dumper;

my @passwordSalt = (
    0x4e, 0x74, 0x67, 0x72,
    0x53, 0x6d, 0x61, 0x72,
    0x74, 0x53, 0x77, 0x69,
    0x74, 0x63, 0x68, 0x52,
    0x6f, 0x63, 0x6b
);

my $sock = IO::Socket::INET->new(
    Proto     => 'udp',
    LocalAddr => '0.0.0.0',
#    LocalAddr => '192.168.0.254',
    Broadcast => 1,
    LocalPort => 63321,
    ReuseAddr => 1
    ) or die "Can't bind : $@\n";

$sock->sockopt(SO_BROADCAST() => 1);

my $select = IO::Select->new($sock);
my $seq = rand(65535);
my $state = 0;
my $portcount = 5;
my $DEBUG = 1;
my $swmac = "\x00\x00\x00\x00\x00\x00";		# Initial value of switch mac address
my $selfmac = "";				# MAC address of network interface, used for communications witch switch
my $DST_ADDR = pack('CCCC', 255,255,255,255);	# broadcast address, if your system has multiple interfaces,
						# then use local broadcast for selected network interface

getConfig($sock, $seq++);
printf "Waiting for reply from device...\n" if $DEBUG;

my $isAlive = 1;
while($isAlive) {
    my @ready = $select->can_read(1);
    if (@ready) {
	my $data = undef;
	my $from = recv($sock, $data, 1500, 0) || die "recv: $!";
	my($port, $from_addr) = sockaddr_in($from);
	my @hexdata = unpack("C*", $data);
	printf "Recv:[%s]\n", join(' ', map(sprintf("0x%.2x", $_), @hexdata)) if $DEBUG;

	parseNSDP($data);

	my $offset = 32;
	my $isDone = 0;
	while(!($isDone) && $offset < length($data)) {
	    my $type = unpack("n", substr($data, $offset)); $offset += 2;
	    if ($type == 0x0000) {
		$isDone = 1;
		print "\n";
		next;
	    }
	    if ($type == 0xffff) {
		$isDone = 1;
		print "\n";
		next;
	    }
	    my $len = unpack("n", substr($data, $offset)); $offset += 2;
	    my $val = substr($data, $offset, $len); $offset += $len;
	    if ($type == 0x0001) {
		$val =~ s/ +//;
		printf "Device Model: %s\n", $val;
		next;
	    }
	    if ($type == 0x0003) {
		$val =~ s/ +//;
		printf "Device Name: %s\n", $val;
		next;
	    }
	    if ($type == 0x0004) {
		printf "MAC: %s\n", join(':', map(sprintf("%.2x", $_), unpack("C*", $val)));
		$swmac = $val;
		next;
	    }
	    if ($type == 0x0006) {
		printf "IP Address: %s\n", join('.', unpack("C*", $val));
		next;
	    }
	    if ($type == 0x0007) {
		printf "Network Mask: %s\n", join('.', unpack("C*", $val));
		next;
	    }
	    if ($type == 0x0008) {
		printf "Gateway: %s\n", join('.', unpack("C*", $val));
		next;
	    }
	    if ($type == 0x000b) {
		my $val = unpack('C', $val);
		printf "DHCP Client: %d\n", $val if defined($val);
		next;
	    }
	    if ($type == 0x000d) {
		printf "Firmware version: %s\n", $val;
		next;
	    }
	    if ($type == 0x0010) {
		my $val = unpack('C', $val);
		printf "TFTP Server: %d\n", $val if defined($val);
		next;
	    }
	    if ($type == 0x0c00) {
#		my $val = substr($data, $offset, $len); $offset += $len;
		my($port, $speed, $duplex) = unpack('CCC', $val);
		printf "Port status: %d, Speed: %s, Duplex: %d\n", $port, portSpeed($speed), $duplex;
		next;
	    }
	    if ($type == 0x1000) {
		my @stat = unpack('CNNNNNNNNNNNN', $val);
		printf "Packet statistics: %d,%d,%d,%d,%d,%d,%d\n", $stat[0], $stat[1], $stat[3], $stat[5], $stat[7], $stat[9], $stat[11];
		next;
	    }
	    if ($type == 0x1c00) {
		printf "Port diagbostics %s\n", join(' ', map(sprintf('%.2x', $_), unpack('C'.$len, $val)));
		next;
	    }
	    if ($type == 0x2000) {
		my $val = unpack('C', $val);
		printf "VLAN mode: %d\n", $val if defined($val);
		next;
	    }
	    if ($type == 0x2800) {
		my($vlan, $membership) = unpack('na2', $val);
		next if !(defined($vlan) && defined($membership));
		my($mports, $tags) = unpack('CC', $membership);
		my $pvids = $mports ^ $tags;
		printf "VLAN: %.4d m:%s t:%s p:%s\n",
		    $vlan,
		    substr(unpack('B8', pack('C', $mports)), 0, $portcount),
		    substr(unpack('B8', pack('C', $tags)), 0, $portcount),
		    substr(unpack('B8', pack('C', $pvids)), 0, $portcount);
		next;
	    }
	    if ($type == 0x5c00) {
		printf "Port miroring mode: %s\n", join(' ', map(sprintf('%.2x', $_), unpack('C*', $val)));
		next;
	    }
	    if ($len == 0x01) {
		printf "%.4x(%.4x)=%.2x\n", $type, $len, unpack('C', $val) if $DEBUG;
		next;
	    }
	    if ($len == 0x02) {
		printf "%.4x(%.4x)=%.4x\n", $type, $len, unpack('n', $val) if $DEBUG;
		next;
	    }
	    printf "%.4x(%.4x)\n", $type, $len if $DEBUG;
	}
    } else {
	$isAlive = 0;
    }
}
if (defined($ARGV[0])) {
    if ($ARGV[0] eq '-w') {
	setConfig($sock, $seq++, $swmac, 'password');
	my @ready = $select->can_read(30);
	if (@ready) {
	    my $data = undef;
	    my $from = recv($sock, $data, 1500, 0) || die "recv: $!";
	    my($port, $from_addr) = sockaddr_in($from);
	    my @hexdata = unpack("C*", $data);
	    printf "Recv:[%s]\n", join(' ', map(sprintf("0x%.2x", $_), @hexdata)) if $DEBUG;

	    parseNSDP($data);
	}
    }
}

$sock->close();

exit;

sub getConfig {
    my $sock = shift;
    my $seq = shift;
    my $msg = pack('na6a6a6Sna4N', 0x0101, "\x00\x00\x00\x00\x00\x00", $selfmac, "\x00\x00\x00\x00\x00\x00", 0x0000, $seq, "NSDP", 0x00000000);
    $msg .= "\x00\x01\x00\x00";
    $msg .= "\x00\x02\x00\x00";
    $msg .= "\x00\x03\x00\x00";
    $msg .= "\x00\x04\x00\x00";
    $msg .= "\x00\x05\x00\x00";
    $msg .= "\x00\x06\x00\x00";
    $msg .= "\x00\x07\x00\x00";
    $msg .= "\x00\x08\x00\x00";
    $msg .= "\x00\x0b\x00\x00";
    $msg .= "\x00\x0c\x00\x00";
    $msg .= "\x00\x0d\x00\x00";
    $msg .= "\x00\x0f\x00\x00";
    $msg .= "\x0c\x00\x00\x00";
#    $msg .= "\x10\x00\x00\x00";
#    $msg .= "\x1c\x00\x00\x00";
    $msg .= "\x20\x00\x00\x00";
    $msg .= "\x28\x00\x00\x00";
#    $msg .= "\x5c\x00\x00\x00";
    $msg .= "\xff\xff\x00\x00";
    my @hexdata = unpack("C*", $msg);
    printf "%s\n", join(' ', map(sprintf("0x%.2x", $_), @hexdata)) if $DEBUG;
    my $dst = sockaddr_in(63322, $DST_ADDR);
    $sock->send($msg, 0, $dst) or die "send: $!";
};

# For Firmware version 1.02.02 and newer
sub saltPassword {
    my @passwordOrigin = unpack("C*", shift);
    my @passwordSalted;
    for (my $i=0; $i < (@passwordOrigin + 0); $i++) {
	$passwordSalted[$i] = $passwordSalt[$i % (@passwordSalt + 0)] ^ $passwordOrigin[$i];
    }
    return pack("C*", @passwordSalted);
};

sub setConfig {
    my $sock = shift;
    my $seq = shift;
    my $swmac = shift;
    my $password = shift;

    my $msg = pack('na6a6a6Sna4N', 0x0103, "\x00\x00\x00\x00\x00\x00", $selfmac, $swmac, 0x0000, $seq, "NSDP", 0x0000);
    $msg .= pack('nna'.length($password), 0x000a, length($password), saltPassword($password)); # TLV with password
    $msg .= pack('nnC', 0x000b, 0x0001, 1); # DHCP mode On|Off
    $msg .= pack('nnCCCC', 0x0006, 0x0004, 192,168,0,239); # Device IP address
    $msg .= pack('nnCCCC', 0x0007, 0x0004, 255,255,255,0); # Device IP address
    $msg .= pack('nnCCCC', 0x0008, 0x0004, 192,168,0,254); # GW IP address

    $msg .= pack('nnC', 0x2000, 0x0001, 0x04); # Enable advanced 8021q VLANs
    $msg .= pack('nnnCC', 0x2800, 0x0004, 0001, unpack('C', pack('B8', '11111000')), unpack('C', pack('B8', '11111000'))); # vlan, memeber then tagged ports

    $msg .= pack('nn', 0xffff, 0x0000); # trailer
    my @hexdata = unpack("C*", $msg);
    printf "%s\n", join(' ', map(sprintf("0x%.2x", $_), @hexdata));
    my $dst = sockaddr_in(63322, $DST_ADDR);
    $sock->send($msg, 0, $dst) or die "send: $!";
};

sub parseNSDP {
    my $data = shift;
    my($ctype, $result, $reserved, $selfmac, $dstmac, $reserved1, $seq, $sign, $reserved2) = unpack('nna4a6a6a2na4Nn', $data);
    my @selfmac_ = unpack('C6', $selfmac);
    my @dstmac_ = unpack('C6', $dstmac);
    printf "ctype=%.4x\n", $ctype if $DEBUG;
    printf "result=%.4x\n", $result if $DEBUG;
    printf "selfmac=%s\n", join(':', map(sprintf("%.2x", $_), @selfmac_)) if $DEBUG;
    printf "dstmac=%s\n", join(':', map(sprintf("%.2x", $_), @dstmac_)) if $DEBUG;
    printf "seq=%.4x\n", $seq if $DEBUG;
    printf "sign=%s\n", $sign if $DEBUG;
};

# --------------------------

sub portSpeed {
    my $speed = shift;
    return "Down" if 0 == $speed;
    return "10M" if 1 == $speed;
    return "100M" if 4 == $speed;
    return "1000M" if 5 == $speed;
};