build.gradle

plugins {
    id 'eclipse'
}

def env = System.getenv()

subprojects {
    apply plugin: 'java-library'
    if (project.noPublish == 'false') apply plugin: 'maven-publish'

    java {
        withSourcesJar()

        toolchain {
            languageVersion.set(JavaLanguageVersion.of(17))
        }
    }

    if (project.noPublish == 'false') {
        publishing {
            publications {
                mavenJava(MavenPublication) {
                    groupId = project.group
                    artifactId = "nahara-${project.name}"
                    version = project.version
                    from components.java
                }
            }
    
            repositories {
                mavenLocal()
    
                if (env.mavenUrl) {
                    println "Maven Publish: Found Maven URL from envvar"
                    maven {
                        url env.mavenUrl
                        if (env.mavenUsername) {
                            credentials {
                                username env.mavenUsername
                                password env.mavenPassword
                            }
                        }
                    }
                }
            }
        }
    }
}