settings.gradle

pluginManagement {
    repositories {
        maven { url = "https://maven.fabricmc.net/" }
        maven { url = "https://maven.architectury.dev/" }
        maven { url = "https://maven.minecraftforge.net/" }
        maven { url = "https://maven.quiltmc.org/repository/release" }
        gradlePluginPortal()
    }
}

dependencyResolutionManagement {
    repositories {
        mavenCentral()
    }
    versionCatalogs {
        // Minecraft Version
        def minecraftVersion = "1.20.1"

        def jeiVersion = "15.2.0.27"
        def reiVersion = "12.0.684"
        def emiVersion = "1.1.4"
        def forgeVersion = "47.2.23"

        // Libs
        def quiltMappingsVersion = "5"  // https://lambdaurora.dev/tools/import_quilt.html
        def parchmentVersion = "2023.09.03" // https://parchmentmc.org/docs/getting-started
        def shadowVersion = "7.1.2"
        def architecturyPluginVersion = "3.4-SNAPSHOT"
        def architecturyLoomVersion = "1.6-SNAPSHOT"
        def vineFlowerVersion = "1.11.0"
        def macheteVersion = "1.+"

        common {
            version("forgeShortVersion", forgeVersion)
            def minecraftForge = version("minecratfForge", "${minecraftVersion}-${forgeVersion}")
            library("minecraftForge", "net.minecraftforge", "forge").versionRef(minecraftForge)

            def jei = version("jei", jeiVersion)
            library("jei-forge", "mezz.jei", "jei-${minecraftVersion}-forge").versionRef(jei)
            library("jei-fabric", "mezz.jei", "jei-${minecraftVersion}-fabric").versionRef(jei)

            def rei = version("rei", reiVersion)
            library("rei-forge", "me.shedaniel", "RoughlyEnoughItems-forge").versionRef(rei)
            library("rei-fabric", "me.shedaniel", "RoughlyEnoughItems-fabric").versionRef(rei)

            def emi = version("emi", emiVersion + "+" + minecraftVersion)
            library("emi-forge", "dev.emi", "emi-forge").versionRef(emi)
            library("emi-fabric", "dev.emi", "emi-fabric").versionRef(emi)
        }

        libs {
            version("quiltMappings", quiltMappingsVersion)
            version("parchment", parchmentVersion)

            def minecraft = version("minecraft", minecraftVersion)
            library("minecraft", "com.mojang", "minecraft").versionRef(minecraft)

            def shadow = version("shadow", shadowVersion)
            plugin("shadow", "com.github.johnrengelman.shadow").versionRef(shadow)

            def architecturyPlugin = version("architectury", architecturyPluginVersion)
            plugin("architectury", "architectury-plugin").versionRef(architecturyPlugin)

            def architecturyLoom = version("architectury-loom", architecturyLoomVersion)
            plugin("architectury-loom", "dev.architectury.loom").versionRef(architecturyLoom)

            def vineFlower = version("vineFlower", vineFlowerVersion)
            plugin("vineFlower", "io.github.juuxel.loom-vineflower").versionRef(vineFlower)

            def machete = version("machete", macheteVersion)
            plugin("machete", "io.github.p03w.machete").versionRef(machete)
        }
    }
}

rootProject.name = 'ExtraSoundsNext'

include 'common'
include 'fabric'
include 'forge'