Add placeable and carryable flags

addons/flags/$PBOPREFIX$

@@ -0,0 +1 @@
+z\ace\addons\flags

addons/flags/CfgEventHandlers.hpp

@@ -0,0 +1,23 @@
+class Extended_PreStart_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_SCRIPT(XEH_preStart));
+    };
+};
+
+class Extended_PreInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_SCRIPT(XEH_preInit));
+    };
+};
+
+class Extended_PostInit_EventHandlers {
+    class ADDON {
+        init = QUOTE(call COMPILE_SCRIPT(XEH_postInit));
+    };
+};
+
+class Extended_DisplayLoad_EventHandlers {
+    class RscDisplayMission {
+        ADDON = QUOTE(_this call COMPILE_SCRIPT(XEH_missionDisplayLoad));
+    };
+};

addons/flags/CfgVehicles.hpp

@@ -0,0 +1,22 @@
+class CfgVehicles {
+    class Man;
+    class CAManBase: Man {
+        class ACE_SelfActions {
+            class ACE_Equipment {
+                class ADDON {
+                    displayName = CSTRING(ActionCategory);
+                    condition = QUOTE(_player call FUNC(hasFlag));
+                    insertChildren = QUOTE(_this call FUNC(getActions));
+                    icon = QPATHTOF(data\icons\place\white_place_icon.paa);
+
+                    class GVAR(furlFlag) {
+                        displayName = CSTRING(Furl);
+                        condition = QUOTE(_player call FUNC(carriesFlag));
+                        statement = QUOTE(_player call FUNC(furlFlag));
+                        icon = QPATHTOF(data\icons\carry\white_furl_icon.paa);
+                    };
+                };
+            };
+        };
+    };
+};

addons/flags/CfgWeapons.hpp

@@ -0,0 +1,78 @@
+class CfgWeapons {
+    class ACE_ItemCore;
+    class CBA_MiscItem_ItemInfo;
+
+    class GVAR(white): ACE_ItemCore {
+        scope = 2;
+        author = ECSTRING(common,ACETeam);
+        descriptionShort = CSTRING(Description);
+        descriptionUse = CSTRING(Description);
+
+        displayName = CSTRING(White);
+        picture = QPATHTOF(data\pictures\white_item.paa);
+
+        GVAR(texture) = "\a3\data_f\flags\flag_white_co.paa";
+        GVAR(actionIconPlace) = QPATHTOF(data\icons\place\white_place_icon.paa);
+        GVAR(actionIconCarry) = QPATHTOF(data\icons\carry\white_carry_icon.paa);
+
+        class ItemInfo: CBA_MiscItem_ItemInfo {
+            mass = 3;
+        };
+    };
+    class GVAR(red): GVAR(white) {
+        displayName = CSTRING(Red);
+        picture = QPATHTOF(data\pictures\red_item.paa);
+
+        GVAR(texture) = "\a3\data_f\flags\flag_red_co.paa";
+        GVAR(actionIconPlace) = QPATHTOF(data\icons\place\red_place_icon.paa);
+        GVAR(actionIconCarry) = QPATHTOF(data\icons\carry\red_carry_icon.paa);
+    };
+    class GVAR(blue): GVAR(white) {
+        displayName = CSTRING(Blue);
+        picture = QPATHTOF(data\pictures\blue_item.paa);
+
+        GVAR(texture) = "\a3\data_f\flags\Flag_blue_co.paa";
+        GVAR(actionIconPlace) = QPATHTOF(data\icons\place\blue_place_icon.paa);
+        GVAR(actionIconCarry) = QPATHTOF(data\icons\carry\blue_carry_icon.paa);
+    };
+    class GVAR(green): GVAR(white) {
+        displayName = CSTRING(Green);
+        picture = QPATHTOF(data\pictures\green_item.paa);
+
+        GVAR(texture) = "\a3\data_f\flags\flag_green_co.paa";
+        GVAR(actionIconPlace) = QPATHTOF(data\icons\place\green_place_icon.paa);
+        GVAR(actionIconCarry) = QPATHTOF(data\icons\carry\green_carry_icon.paa);
+    };
+    class GVAR(yellow): GVAR(white) {
+        displayName = CSTRING(Yellow);
+        picture = QPATHTOF(data\pictures\yellow_item.paa);
+
+        GVAR(texture) = QPATHTOF(data\Flag_yellow_co.paa);
+        GVAR(actionIconPlace) = QPATHTOF(data\icons\place\yellow_place_icon.paa);
+        GVAR(actionIconCarry) = QPATHTOF(data\icons\carry\yellow_carry_icon.paa);
+    };
+    class GVAR(orange): GVAR(white) {
+        displayName = CSTRING(Orange);
+        picture = QPATHTOF(data\pictures\orange_item.paa);
+
+        GVAR(texture) = QPATHTOF(data\flag_orange_co.paa);
+        GVAR(actionIconPlace) = QPATHTOF(data\icons\place\orange_place_icon.paa);
+        GVAR(actionIconCarry) = QPATHTOF(data\icons\carry\orange_carry_icon.paa);
+    };
+    class GVAR(purple): GVAR(white) {
+        displayName = CSTRING(Purple);
+        picture = QPATHTOF(data\pictures\purple_item.paa);
+
+        GVAR(texture) = QPATHTOF(data\flag_purple_co.paa);
+        GVAR(actionIconPlace) = QPATHTOF(data\icons\place\purple_place_icon.paa);
+        GVAR(actionIconCarry) = QPATHTOF(data\icons\carry\purple_carry_icon.paa);
+    };
+    class GVAR(black): GVAR(white) {
+        displayName = CSTRING(Black);
+        picture = QPATHTOF(data\pictures\black_item.paa);
+
+        GVAR(texture) = QPATHTOF(data\flag_black_co.paa);
+        GVAR(actionIconPlace) = QPATHTOF(data\icons\place\black_place_icon.paa);
+        GVAR(actionIconCarry) = QPATHTOF(data\icons\carry\black_carry_icon.paa);
+    };
+};

addons/flags/README.md

@@ -0,0 +1,4 @@
+ace_flags
+===================
+
+Adds placeable and carryable flags with a variety of colors.

addons/flags/XEH_PREP.hpp

@@ -0,0 +1,8 @@
+PREP(carriesFlag);
+PREP(carryFlag);
+PREP(furlFlag);
+PREP(getActions);
+PREP(getFlags);
+PREP(handleScrollWheel);
+PREP(pickupFlag);
+PREP(placeFlag);

addons/flags/XEH_missionDisplayLoad.sqf

@@ -0,0 +1,17 @@
+#include "script_component.hpp"
+
+if (!hasInterface) exitWith {};
+
+params ["_display"];
+
+_display displayAddEventHandler ["MouseZChanged", {
+    params ["", "_scroll"];
+    [_scroll] call FUNC(handleScrollWheel);
+}];
+
+_display displayAddEventHandler ["MouseButtonDown", {
+    params ["", "_button"];
+    if (GVAR(isPlacing) isNotEqualTo PLACE_WAITING) exitWith {false};
+    if (_button isNotEqualTo 1) exitWith {false}; // 1 = Left mouse button
+    GVAR(isPlacing) = PLACE_CANCEL;
+}];

addons/flags/XEH_postInit.sqf

@@ -0,0 +1,39 @@
+#include "script_component.hpp"
+
+if (!hasinterface) exitWith {};
+
+GVAR(isPlacing) = PLACE_CANCEL;
+["ace_interactMenuOpened", {GVAR(isPlacing) = PLACE_CANCEL;}] call CBA_fnc_addEventHandler;
+
+[QGVAR(flagPlaced), {
+    params ["_unit", "_item", "_flag"];
+
+    (GVAR(flagItemCache) get _item) params ["_flagName"];
+
+    private _pickupFlag = [
+        QGVAR(pickup),
+        format [LLSTRING(Pickup), _flagName],
+        QPATHTOF(data\icons\place\white_pickup_icon.paa),
+        {
+            params ["_flag", "_unit", "_item"];
+            [_unit, _item, _flag] call FUNC(pickupFlag);
+        },
+        {true},
+        {},
+        _item,
+        [0, -0.45, 0.75],
+        2
+    ] call ace_interact_menu_fnc_createAction;
+    [_flag, 0, [], _pickupFlag] call ace_interact_menu_fnc_addActionToObject;
+}] call CBA_fnc_addEventHandler;
+
+private _flagItems = (call (uiNamespace getVariable [QGVAR(allFlagItems), {[]}])) apply {configFile >> "CfgWeapons" >> _x};
+{
+    private _name = configName _x;
+    private _displayName = getText (_x >> "displayName");
+    private _texture = getText (_x >> QGVAR(texture));
+    private _actionIconPlace = getText (_x >> QGVAR(actionIconPlace));
+    private _actionIconCarry = getText (_x >> QGVAR(actionIconCarry));
+
+    GVAR(flagItemCache) set [_name, [_displayName, _texture, _actionIconPlace, _actionIconCarry]];
+} forEach _flagItems;

addons/flags/XEH_preInit.sqf

@@ -0,0 +1,13 @@
+#include "script_component.hpp"
+
+ADDON = false;
+
+PREP_RECOMPILE_START;
+#include "XEH_PREP.hpp"
+PREP_RECOMPILE_END;
+
+#include "initSettings.sqf"
+
+GVAR(flagItemCache) = createHashMap;
+
+ADDON = true;

addons/flags/XEH_preStart.sqf

@@ -0,0 +1,6 @@
+#include "script_component.hpp"
+
+#include "XEH_PREP.hpp"
+
+private _flagItems = (configProperties [configfile >> "CfgWeapons", QUOTE(isClass _x && (isText (_x >> QQGVAR(texture)))), true]) apply {configName _x};
+uiNamespace setVariable [QGVAR(allFlagItems), compileFinal str _flagItems];

addons/flags/config.cpp

@@ -0,0 +1,28 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        name = COMPONENT_NAME;
+        units[] = {};
+        weapons[] = {
+            QGVAR(white),
+            QGVAR(red),
+            QGVAR(blue),
+            QGVAR(green),
+            QGVAR(yellow),
+            QGVAR(orange),
+            QGVAR(purple),
+            QGVAR(black)
+        };
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {"ace_common", "ace_interact_menu", "ace_interaction"};
+        author = ECSTRING(common,ACETeam);
+        authors[] = {"Timi007"};
+        url = ECSTRING(main,URL);
+        VERSION_CONFIG;
+    };
+};
+
+#include "CfgEventHandlers.hpp"
+#include "CfgVehicles.hpp"
+#include "CfgWeapons.hpp"

addons/flags/functions/fnc_carriesFlag.sqf

@@ -0,0 +1,21 @@
+#include "script_component.hpp"
+/*
+ * Author: Timi007
+ * Checks if the unit is carrying a flag.
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ *
+ * Return Value:
+ * True if unit is carrying a flag; otherwise flase <BOOLEAN>
+ *
+ * Example:
+ * [player] call ace_flags_fnc_carriesFlag
+ *
+ * Public: No
+ */
+
+params ["_unit"];
+
+(_unit getVariable [QGVAR(carryingFlag), ""] isNotEqualTo "") &&
+{(getForcedFlagTexture _unit) isNotEqualTo ""}

addons/flags/functions/fnc_carryFlag.sqf

@@ -0,0 +1,26 @@
+#include "script_component.hpp"
+/*
+ * Author: Timi007
+ * Attaches flag to the back of the unit and removes his flag item.
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ * 1: Flag item <STRING>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * [player, "ace_flags_white"] call ace_flags_fnc_carryFlag
+ *
+ * Public: No
+ */
+
+params ["_unit", "_item"];
+TRACE_2("Carry flag", _unit, _item);
+
+(GVAR(flagItemCache) get _item) params ["", "_texture"];
+_unit forceFlagTexture _texture;
+
+_unit setVariable [QGVAR(carryingFlag), _item, true];
+_unit removeItem _item;

addons/flags/functions/fnc_furlFlag.sqf

@@ -0,0 +1,26 @@
+#include "script_component.hpp"
+/*
+ * Author: Timi007
+ * Stops carrying flag and adds flag item back to unit.
+ *
+ * Arguments:
+ * 0: Unit <OBJECT>
+ *
+ * Return Value:
+ * Nothing
+ *
+ * Example:
+ * [player] call ace_flags_fnc_furlFlag
+ *
+ * Public: No
+ */
+
+params ["_unit"];
+
+// Stop carrying flag and add flag item to unit.
+_item = _unit getVariable [QGVAR(carryingFlag), ""];
+_unit setVariable [QGVAR(carryingFlag), nil, true];
+
+_unit forceFlagTexture ""; // Remove flag
+
+[_unit, _item] call EFUNC(common,addToInventory);

addons/flags/functions/fnc_getActions.sqf

@@ -0,0 +1,62 @@
+#include "script_component.hpp"
+/*
+ * Author: Timi007
+ * Gets the child actions for placing and carring flags.
+ *
+ * Arguments:
+ * 0: Player <OBJECT>
+ *
+ * Return Value:
+ * Actions <ARRAY>
+ *
+ * Example:
+ * [player] call ace_flags_fnc_getActions
+ *
+ * Public: No
+ */
+
+params ["_player"];
+
+private _actions = [];
+
+{
+    (GVAR(flagItemCache) get _x) params ["_flagName", "_texture", "_actionIconPlace", "_actionIconCarry"];
+
+    // Place flag
+    _actions pushBack [
+        [
+            "place_" + _x,
+            format [LLSTRING(Place), _flagName],
+            _actionIconPlace,
+            {
+                params ["_player", "", "_item"];
+                [_player, _item] call FUNC(placeFlag);
+            },
+            {GVAR(enablePlacing)},
+            {},
+            _x
+        ] call EFUNC(interact_menu,createAction),
+        [],
+        _player
+    ];
+
+    // Carry flag
+    _actions pushBack [
+        [
+            "carry_" + _x,
+            format [LLSTRING(Carry), _flagName],
+            _actionIconCarry,
+            {
+                params ["_player", "", "_item"];
+                [_player, _item] call FUNC(carryFlag);
+            },
+            {GVAR(enableCarrying) && {!([_this select 0] call FUNC(carriesFlag))}}, // Should not carry flag already
+            {},
+            _x
+        ] call EFUNC(interact_menu,createAction),
+        [],
+        _player
+    ];
+} forEach ([_player] call FUNC(getFlags));
+
+_actions